TVM
Angelegt Sonntag 18 Oktober 2026
Time Value for Money - ein Programm für den Taschenrechner
Beispielrechnung:
FIX 4
[RUN FL=0] go
Finanzrechnung
1 N Anzahl Perioden
2 PV Startwert
3 FV Endwert
4 PMT Rate
5 I Zinssatz/Periode
Welcher Parameter soll berechnet werden (1-5)? 5
N Anzahl Perioden? 60
PV Startwert? 15000
FV Endwert? 0
PMT Rate? -300
Periodenzins = 0.0062 Jahreszins = 7.4201
X=0.0062 Y=0.6183 Z=7.4201 W=0.0000
Das Programm im Modus PRGM eingeben oder als Datei TVM.txt in den Ordner ~/.taschenrechner/Programme legen und dann mit load TVM.txt laden.
SLOFF
PRINT "Finanzrechnung"
PRINT
PRINT "1 N Anzahl Perioden"
PRINT "2 PV Startwert"
PRINT "3 FV Endwert"
PRINT "4 PMT Rate"
PRINT "5 I Zinssatz/Periode"
PRINT
INPUT 0 "Welcher Parameter soll berechnet werden (1-5)"
PRINT
RCL 0
ENTER
NUM 1
X=Y
GTO N
NUM 2
X=Y
GTO PV
NUM 3
X=Y
GTO FV
NUM 4
X=Y
GTO PMT
NUM 5
X=Y
GTO I
PRINT "Ungueltig (1-5)"
RTN
LBL N
INPUT 2 "PV Startwert"
INPUT 3 "FV Endwert"
INPUT 4 "PMT Rate"
INPUT 5 "I Zinssatz/Periode"
RCL 3
ENTER
RCL 5
*
STO 13
RCL 13
ENTER
RCL 4
+
STO 14
RCL 2
ENTER
RCL 5
*
STO 15
RCL 15
ENTER
RCL 4
+
STO 16
RCL 14
ENTER
RCL 16
/
STO 17
RCL 17
LN
STO 18
RCL 5
ENTER
NUM 1
+
STO 10
RCL 10
LN
STO 19
RCL 18
ENTER
RCL 19
/
STO 1
PRINT "Ergebnis N = %x"
RTN
LBL PV
INPUT 1 "N Anzahl Perioden"
INPUT 3 "FV Endwert"
INPUT 4 "PMT Rate"
INPUT 5 "I Zinssatz/Periode"
RCL 5
ENTER
NUM 1
+
STO 10
RCL 10
ENTER
RCL 1
Y^X
STO 11
RCL 11
INV
STO 12
RCL 3
ENTER
RCL 12
*
STO 13
NUM 1
ENTER
RCL 12
-
STO 14
RCL 4
ENTER
RCL 14
*
STO 15
RCL 15
ENTER
RCL 5
/
STO 16
RCL 13
ENTER
RCL 16
-
STO 2
PRINT "Ergebnis PV = %x"
RTN
LBL FV
INPUT 1 "N Anzahl Perioden"
INPUT 2 "PV Startwert"
INPUT 4 "PMT Rate"
INPUT 5 "I Zinssatz/Periode"
RCL 5
ENTER
NUM 1
+
STO 10
RCL 10
ENTER
RCL 1
Y^X
STO 11
RCL 2
ENTER
RCL 11
*
STO 13
RCL 11
ENTER
NUM 1
-
STO 14
RCL 4
ENTER
RCL 14
*
STO 15
RCL 15
ENTER
RCL 5
/
STO 16
RCL 13
ENTER
RCL 16
+
STO 3
PRINT "Ergebnis FV = %x"
RTN
LBL PMT
INPUT 1 "N Anzahl Perioden"
INPUT 2 "PV Startwert"
INPUT 3 "FV Endwert"
INPUT 5 "I Zinssatz/Periode"
RCL 5
ENTER
NUM 1
+
STO 10
RCL 10
ENTER
RCL 1
Y^X
STO 11
RCL 2
ENTER
RCL 11
*
STO 13
RCL 3
ENTER
RCL 13
-
STO 14
RCL 14
ENTER
RCL 5
*
STO 15
RCL 11
ENTER
NUM 1
-
STO 16
RCL 15
ENTER
RCL 16
/
STO 4
PRINT "Ergebnis PMT = %x"
RTN
LBL I
INPUT 1 "N Anzahl Perioden"
INPUT 2 "PV Startwert"
INPUT 3 "FV Endwert"
INPUT 4 "PMT Rate"
NUM 0.05
STO 6
NUM 50
STO 20
NUM 0.0001
STO 21
LBL ITER
RCL 6
STO 27
CALL F
RCL 7
STO 22
RCL 6
ENTER
RCL 21
+
STO 6
CALL F
RCL 7
STO 23
RCL 27
STO 6
RCL 23
ENTER
RCL 22
-
STO 24
RCL 24
ENTER
RCL 21
/
STO 25
RCL 22
ENTER
RCL 25
/
STO 26
RCL 6
ENTER
RCL 26
-
STO 6
DSG 20
GTO ITER
RCL 6
STO 5
DUP
DUP
NUM 100
*
DUP
DUP
NUM 12
*
CHT
X<>Y
CHT
SLON
PRINT "Periodenzins = %x Jahreszins = %z"
PRINT
RTN
LBL F
RCL 6
ENTER
NUM 1
+
STO 10
RCL 10
ENTER
RCL 1
Y^X
STO 11
RCL 2
ENTER
RCL 11
*
STO 13
RCL 11
ENTER
NUM 1
-
STO 14
RCL 4
ENTER
RCL 14
*
STO 15
RCL 15
ENTER
RCL 6
/
STO 16
RCL 13
ENTER
RCL 16
+
STO 17
RCL 17
ENTER
RCL 3
-
STO 7
RTN
Backlinks: Z-Blog:Taschenrechner